-- card: 13890 from stack: in.5
-- bmap block id: 14927
-- flags: 0000
-- background id: 14562
-- name: Report Bugs
----- HyperTalk script -----
on OpenCard
  -- try to avoid empty messages being sent and people losing comments
  --  by going to another card before sending
  global STFEEDBACKLENGTH
  put length(cd fld "link text") + length(cd fld "system report") into STFEEDBACKLENGTH
end OpenCard

on DoMenu whichMenu
  -- see if the requested menu action will leave this card
  if whichMenu is in "Quit HyperCard,Open Stack...,New Stack..." && "Home,Back,Recent,Help,First,Next,Prev,Last" then
    if not OKToLeave() then exit DoMenu
  end if
  pass DoMenu
end DoMenu

function OKToLeave
-- try to avoid empty messages being sent and people losing comments
--  by going to another card before sending when the stack is locked
global STFEEDBACKLENGTH
put length(cd fld "link text") + length(cd fld "system report") into currLength
if currLength ≠ STFEEDBACKLENGTH and the cantmodify of this stack then
  -- something has changed since entering the card, and the stack is
  --  locked.  make sure they mean to lose their comments
  answer "Leaving the card now will loose your valuable comments." && " Leave this card anyway?" with "Yes" or "No"
  if it = "No" then return false  -- don't leave yet
end if
return true     -- OK to leave
end OKToLeave


-- part 8 (button)
-- low flags: 00
-- high flags: A001
-- rect: left=225 top=293 right=339 bottom=288
-- title width / last selected line: 0
-- icon id / first selected line: 1099 / 1099
-- text alignment: 1
-- font id: 3
-- text size: 18
-- style flags: 0
-- line height: 24
-- part name: AppleLink
----- HyperTalk script -----
on mouseUp
  -- 9:44 AM 11/12/90 ec
  --
  global STFEEDBACKLENGTH
  -- has a system report been generated?
  -- how about a typed message?
  put length(cd fld "link text") + length(cd fld "system report") into currLength
  if currLength = STFEEDBACKLENGTH then
    answer "Don't you want to add any comments?" with "No" or "Oh, yeah…"
    if it =  "Oh, yeah…" then exit mouseUp
  end if

  answer "What version of AppleLink will you be using?" with "Cancel" or "4.0" or "5.0"
  if it is "Cancel" then
    exit mouseUp
  end if
  put it into modeOfTransport

  -- build up the text to print
  put cd fld "link text" & return into snoopInfo
  repeat 50 times
    put "—" after snoopInfo
  end repeat
  put return & cd fld "system report" after snoopInfo

  if modeOfTransport = "4.0" then
    MakeSendMe4 "cyNic","","System configuration",snoopInfo
  else if modeOfTransport = "5.0" then
    MakeSendMe5 "cyNic","","System configuration",snoopInfo
  end if

  answer "A file has been put into your AppleLink outbasket folder" && "(in your system folder).  It will appear in your outbasket when" && " you next log onto AppleLink.  Please sent it then."
end mouseUp



-- part 15 (button)
-- low flags: 00
-- high flags: A001
-- rect: left=69 top=293 right=339 bottom=149
-- title width / last selected line: 0
-- icon id / first selected line: 1128 / 1128
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Generate Report
----- HyperTalk script -----
on mouseUp
  global xErr
  set cursor to busy
  if the visible of cd fld "HELP!" then send "mouseUp" to cd btn "HELP!"
  put "Reading system parameters…"
  put "••••• Configuration: " & return & SysEnvironment() & return & return into sysStr

  DegubStr "SysEnvironment" & return & sysStr

  put sysStr into cd fld "system report"

  put "Reading Applications running…"
  put "••••• Applications running:" & return after cd fld "system report"
  if MFIsRunning() then
    put ApplicationList() & return & return into sysStr

    DegubStr "ApplicationList" & return & sysStr

    put sysStr after cd fld "system report"
  else
    put "HyperCard" & return & return after cd fld "system report"
  end if

  put "Reading Open Files…"
  put "••••• Open Files:" & return after cd fld "system report"
  put VolumeList() into theVolumes
  repeat with volNdx = 1 to the number of lines in theVolumes
    set cursor to busy
    put line volNdx of theVolumes into aVol
    if aVol ≠ empty then
      put OpenFiles(aVol) & return into sysStr

      DegubStr "OpenFiles" & return & sysStr

      put sysStr after cd fld "system report"
    end if
  end repeat

  put "Reading MultiFinder Version Number"
  -- Find the path to multifinder from the open files list
  put lineOffset(":MultiFinder",cd fld "system report") into mfLineNum
  if mfLineNum ≠ 0 then  -- multifinder in the listing
    put line mfLineNum of cd fld "system report" into mfPath
    put FileVersion(mfPath,"nodialog:errMsg") into mfVersion
    if mfVersion ≠ empty then
      put return & "••••• MultiFinder version:" & return after cd fld "system report"

      DegubStr "FileVersion" & return & mfVersion

      put mfVersion & return & return after cd fld "system report"
    end if
  end if

  put "Reading memory…"
  put "••••• RAM = " & TotalRam()/1024 & "K" & return & return after cd fld "system report"

  put "Reading SCSI Info…"
  put "••••• SCSI Info:" & return after cd fld "system report"
  repeat with SCSINdx = 0 to 6
    set cursor to busy
    put SCSIinfo(SCSINdx,"noDialog:xErr") into SCSIdata
    if SCSIdata <> empty then
      put "•" & SCSINdx & "•" & return & SCSIdata & return & return into SCSIdata

      DegubStr "SCSI" & return & SCSIdata

      put SCSIdata after cd fld "system report"
    end if
    put empty into xErr
  end repeat
  put return after cd fld "system report"

  put "Reading Monitor Info:"
  put "••••• Monitor Info:" & return after cd fld "system report"
  repeat with MonitorNdx = 1 to MonitorCount()
    set cursor to busy
    put monitorConfig(MonitorNdx) into MonitorInfo
    if MonitorInfo <> empty then

      DegubStr "MonitorInfo" & return & MonitorInfo

      put MonitorInfo after cd fld "system report"
    end if
  end repeat

  set cursor to busy
  put "Reading INIT Info:"
  put "••••• INIT Info:" & return after cd fld "system report"
  put INITList("detailed") & return & return after cd fld "system report"

  set cursor to busy
  put "Reading Heapspace:"
  put "••••• Heapspace:" & the heapspace & return after cd fld "system report"

  Put empty
  hide msg

end mouseUp

function lineOffset searchString,anyString
return number of lines of char 1 to offset(searchString,anyString) of anyString
end lineOffset

on DegubStr theText
  -- allows one to see the contents of a variable during script exection
  exit DegubStr  -- disable for now
  set the script of cd btn "temp" to theText
  edit the script of cd btn "temp"
end DegubStr




-- part 7 (button)
-- low flags: 00
-- high flags: A001
-- rect: left=366 top=293 right=339 bottom=430
-- title width / last selected line: 0
-- icon id / first selected line: 302 / 302
-- text alignment: 1
-- font id: 3
-- text size: 18
-- style flags: 0
-- line height: 24
-- part name: Print
----- HyperTalk script -----
on mouseUp
  --
  --  print the system report and message
  --
  global xErr, STFEEDBACKLENGTH
  -- has a system report been generated?
  -- how about a typed message?
  put length(cd fld "link text") + length(cd fld "system report") into currLength
  if currLength = STFEEDBACKLENGTH then
    answer "Don't you want to add any comments?" with "No" or "Oh, yeah…"
    if it =  "Oh, yeah…" then exit mouseUp
  end if

  --
  -- build up the text to print
  put cd fld "link text" & return into snoopInfo
  repeat 50 times
    put "—" after snoopInfo
  end repeat
  put return & cd fld "system report" after snoopInfo

  answer "Are you going to mail this report to us?" with "Cancel" or "Yes" or "No"

  if it = "Cancel" then
    exit mouseUp
  else if it = "Yes" then
    put "Please send to:" & return & return & "Eric Carlson" & return & "Support Tools Development" & return & "Apple Computer Inc." & return & "Mail Stop: 72L" & return & "900 E. Hamilton Ave." & return & "Campbell, Ca. 95008" & return & return & return & return before snoopInfo
  end if

  put "your system configuration" into printPrompt

  PrintContainer snoopInfo,printPrompt,"pagesetup","printjob",times,10, "plain", "noDialog:xErr"

end mouseUp



-- part 9 (field)
-- low flags: 00
-- high flags: 0007
-- rect: left=15 top=190 right=290 bottom=501
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 3
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: system report
----- HyperTalk script -----
on openField
  put random(10) into factor
  if factor < 5 then
    beep
    answer "You wouldn't be changing anything in here" & return & "in order to lie to us, would you?!" with "No, I promise"
  end if
  pass openField
end openField



-- part 10 (field)
-- low flags: 00
-- high flags: 0007
-- rect: left=15 top=93 right=187 bottom=501
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 3
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: link text


-- part 13 (button)
-- low flags: 00
-- high flags: 0001
-- rect: left=129 top=54 right=85 bottom=163
-- title width / last selected line: 0
-- icon id / first selected line: 27104 / 27104
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: HELP!
----- HyperTalk script -----
on mouseUp
  set the hilite of me to not the hilite of me
  set the visible of cd fld "HELP!" to not the visible of cd fld "HELP!"
end mouseUp



-- part 14 (field)
-- low flags: 81
-- high flags: 2007
-- rect: left=15 top=93 right=290 bottom=501
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 3
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: HELP!
----- HyperTalk script -----
on mouseUp
  if the visible of me then
    set the hilite of cd btn "HELP!" to not the visible of cd btn "HELP!"
    hide me
  end if
end mouseUp


-- part 16 (button)
-- low flags: 80
-- high flags: 8004
-- rect: left=333 top=0 right=56 bottom=448
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Temp
----- HyperTalk script -----
MonitorInfo
0,0,640,480
640 x 480
Slot 2
256 Colors
Active
Has menu bar




-- part contents for card part 10
----- text -----
Type the message you wish sent to us into this field and click the 
“Generate Report” button to fill in the field below.
Press the “AppleLink” button below to send these two fields via AppleLink, or press the “Print” button to print the text and mail it.

-- part contents for card part 14
----- text -----
This card is our attempt at getting bug reports and feedback from you.  Use it to send us notes, comments, bug reports, gripes, requests, or anything else you can come up with.

First, click on the Generate Report button.  This button makes use of many of the externals found in this stack.  It generates a detailed description of your system and places it into the lower field.  You can send it to us along with a note or just look over it for your own information.

Next, fill in the upper field with whatever you want.  It will be sent along with your System Report.

Finally, click on the AppleLink button below to send your message and system report to us.  You will be asked what version of AppleLink you are using and then a link will be saved into your AppleLink Out basket.  The next time you log onto AppleLink, you can send the message.  It will automatically be addressed to us.

Click on the Print button below to print a copy of the system report and your message.  The button uses our PrintContainer XCMD.  The text of the report will be printed to the currently chosen printer with our address printed at the top of the page.